Autonomous Transaction yapısını anlatmadan önce transaction yapısına kısaca değinelim. Transaction databasede kod bloğu içerisinde insert, update veya delete işlemlerinin yapılıp, commit veya rollback ile sonlanmasıdır.  Bir kod bloğunun içerisinde birden fazla insert, update veya delete yapılsa bile en son bu işlemden sonra verileceği commit’e (yada rollback) kadar tek bir transaction olarak gerçekleşir. Nedeni ise yapılan bu değişikliklerin commit verilmeden önce sadece değişikliğin yapıldığı sessionda etkili olup, tek bir commit sonrası ise yapılan tüm işlemlerin databasede global olarak etkili olmasıdır.

Autonomous Transaction ise bir transaction içerisinde yeni bir bağımsız transaction açıp işlem yapmadır. Autonomous Transactionu çağıran transaction ana transaction demek daha uygundur.  Autonomous Transaction, ana transaction içerisinde bağımsız bir program gibi çalışıp kendi işlemlerini yapar. Autonomous Transactionda yapılan işlemler ana transactionda yapılan rollback (geri alma işlemi) yapılsa dahi geçerli olur. Ki kullanım amacı da budur. Ana transaction herhangi bir durumda rollback olursa bazı işlemleri garanti altına alıp, rollback mekanizmasının etkisinden kurtulmaktadır. Autonomous Transactionda yapılan işlemlerin ana transactionda görülmesi için kendi içerisinde commit edilmesi gerekmektedir.  Bir transactionın Autonomous Transaction olarak kullanılması için kod bloğu içerisinde PRAGMA AUTONOMOUS_TRANSACTION; kullanılması gerekmektedir. Şimdi bunları daha iyi anlamak için birkaç örnek verelim.

İlk aşamada transactionlarda kullanacağımız tabloyu oluşturalım.

CREATE TABLE TEST_USER.TEMP_INSERT
(INSERT_ID NUMBER UNIQUE, 
INSERT_DESC VARCHAR2(50))
NOLOGGING
NOPARALLEL
NOCACHE;

CREATE TABLE TEST_USER.TEMP_ERROR_LOG
(ERROR_ID NUMBER,
ERROR_DESC VARCHAR2(100))
NOLOGGING
NOPARALLEL
NOCACHE;

Şimdi bu tablo üzerinde bir normal transaction yapan prosedür bir tane de autonomous transaction yapan prosedür oluşturalım.

CREATE OR REPLACE PROCEDURE TEST_USER.SP_TEMP_AT (
   V_ID     IN   NUMBER,
   V_DESC   IN   VARCHAR2
)
IS
   PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
   INSERT INTO TEST_USER.TEMP_ERROR_LOG
        VALUES (V_ID, V_DESC);

   COMMIT;
END;

CREATE OR REPLACE PROCEDURE TEST_USER.SP_TEMP_INSERT
IS
BEGIN
   FOR I IN 1 .. 10
   LOOP
      INSERT INTO TEST_USER.TEMP_INSERT
           VALUES (I, I || '. insert');
   END LOOP;

   COMMIT;
EXCEPTION
   WHEN OTHERS
   THEN
      TEST_USER.SP_TEMP_AT (1, 'insert error');
      ROLLBACK;
END;

Şimdi işlemlere başlayalım.

TRUNCATE TABLE TEST_USER.TEMP_INSERT; -- Table truncated.

TRUNCATE TABLE TEST_USER.TEMP_ERROR_LOG; -- Table truncated.

BEGIN
   TEST_USER.SP_TEMP_INSERT;
END; -- PL/SQL procedure successfully completed.

SELECT * FROM  TEST_USER.TEMP_INSERT;
 
INSERT_ID INSERT_DESC                                       
---------- --------------------------------------------------
         1 1. insert                                         
         2 2. insert                                         
         3 3. insert                                         
         4 4. insert                                         
         5 5. insert                                         
         6 6. insert                                         
         7 7. insert                                         
         8 8. insert                                         
         9 9. insert                                         
        10 10. insert                                        

SELECT * FROM TEST_USER.TEMP_ERROR_LOG;

no rows selected.

Aynı prosedürü tekrar çalıştırıp unique alana aynı değerleri insert ederken exceptiona düşmesini sağlayalım.

BEGIN
   TEST_USER.SP_TEMP_INSERT;
END; -- PL/SQL procedure successfully completed.

İşlem tamamlandı fakat prosedür exceptiona düştü. Şimdi tabloları kontrol edelim.

SELECT * FROM  TEST_USER.TEMP_INSERT;

 INSERT_ID INSERT_DESC                                       
---------- --------------------------------------------------
         1 1. insert                                         
         2 2. insert                                         
         3 3. insert                                         
         4 4. insert                                         
         5 5. insert                                         
         6 6. insert                                         
         7 7. insert                                         
         8 8. insert                                         
         9 9. insert                                         
        10 10. insert 

İlk çalıştırılan prosedürün kayıtları var. İkinci kez çalışan prosedürden kayıtlar insert edilmemiş. Diğer tabloya bakalım.

SELECT * FROM TEST_USER.TEMP_ERROR_LOG;

 ERROR_ID ERROR_DESC                                       
---------- --------------------------------------------------
         1 insert error  

Prosedür exceptiona düşüp rollback etse bile autonomous transaction prosedür bundan etkilenmeyip transactionı kendini içindeki commit ve rollback göre sonlandırmaktadır.