Merhaba 

Yaptığımız geliştirmelerde bazı durumlarda işlemlerin çıktısını almamız gerekebilir. Örnek olarak .txt ya da .csv formatlarını kullanabiliriz. Bir log dosyasını fiziksel olarak disk üzerine kayıt etmek ya da işlem sonucu bir fiziksel dosya olarak almak için utl_file paketini kullanabiliriz. Daha önce blog içerisinde forms ya da reports ile text file ve excel dosyası hazırlanmasını örnek kodlarını paylaşmıştım. Şimdi yapcağımız işlem ise direk database üzerinden fiziksel diskte bir alana veri yazma olacak. Öncelikle utl_file ile dosya yazma işlemini kullanabilmemiz için database üzerinden fiziksel disk üzerinde erişebilmek için bir directory oluşturmalıyız. Ben bu işlem için "C:\" dizini altına "Oracle Directory" kısaltması olarak "OraDir" dosyasını oluşturacağım ve database üzerinden "C:\OraDir" lokasyonunu directory tanımında kullanacağım. Aşağıdaki komut ile fiziksel dosyamızı database üzerinde oradir ismi ile directory oluşturarak kullanacağız.

CREATE DIRECTORY oradir AS 'C:\OraDir\';

Şimdi örnek olarak bir txt dosyası hazırlayalım ve içinde "Merhaba Dünya" yazalım. Bu işlem için aşağıdaki kodu kullanabiliriz.

declare
  vInFileTxt utl_file.file_type;
begin
  vInFileTxt := utl_file.fopen('ORADIR', 'textfile.txt', 'w');

  utl_file.put(vInFileTxt, 'Merhaba ');
  utl_file.put(vInFileTxt, 'Dünya');
  utl_file.put_line(vInFileTxt, ''); --Bir sonraki satıra geçmek için kullandık.
  utl_file.put_line(vInFileTxt, 'Merhaba ve Dünya kelimelerini put komutu ile birleştirdik.');

  utl_file.fclose(vInFileTxt);
exception
  when others then
    dbms_output.put_line('Hata:' || sqlerrm);
end;

Yukarı kod içinde kullandığımız vInFileTxt utl_file.file_type; utl_file için ihtiyacımız olan dosya tipinde değişkenimizi yarattık. utl_file.fopen('ORADIR', 'textfile.txt', 'w'); komutunda ise sırası ile 'ORADIR' directory ismimiz, 'textfile.txt' ise oluşturacağımız dosyanın adı, 'w' komutu ise belirtiğimiz directory altındaki dosyası nasıl açacağımızı belirtiyor. utl_file.fclose(vInFileTxt); komutu ile ise açık olan dosyamızı kapatıyoruz. Dosya açma tipleri ise şu şekilde;

Text file oluşturduk şimdi buna benzer şekilde csv dosyasıda oluşturalım.

declare
  vInFileCsv utl_file.file_type;
begin
  vInFileCsv := utl_file.fopen('ORADIR', 'csvfile.csv', 'w');

  utl_file.put_line(vInFileCsv, 'Sıra;Açıklama;Tarih'); --Başlık bilgileri
  for i in 1 .. 10 loop
    utl_file.put_line(vInFileCsv, i || ';' || i || '. Satır' || ';' || to_char(sysdate, 'dd/mm/yyyy hh24:mi'));--Satır bilgileri
  end loop;
  utl_file.fclose(vInFileCsv);
exception
  when others then
    dbms_output.put_line('Hata:' || sqlerrm);
end;

Hem csv hem de text file hazırladık. Şimdi bu dosyalardan veri okuyalım. Önce text file dosyamızı okuyalım sonrasında ise csv dosyamızın okumasını hazırlayalım.

declare
  vOutFileTxt utl_file.file_type;
  vDeger      varchar2(4000);
begin
  vOutFileTxt := utl_file.fopen('ORADIR', 'textfile.txt', 'r');

  if utl_file.is_open(vOutFileTxt) then
    loop
      begin
        utl_file.get_line(vOutFileTxt, vDeger);

        if vDeger is null then
          exit;
        end if;

        dbms_output.put_line('Okunan Değer:' || vDeger);
      exception
        when no_data_found then
          exit;
      end;
    end loop;

  end if;
  utl_file.fclose(vOutFileTxt);

exception
  when others then
    dbms_output.put_line('Hata:' || sqlerrm);
end;

Kod bloğundaki if utl_file.is_open(vOutFileTxt) then komutu ile dosyamız açık olduğu sürece loop ile satır okumalarını yapıyoruz. utl_file.get_line(vOutFileTxt, vDeger); komutu ile dosya içindeki loop ile elimizde olan satırı vDeger isimli değişkenimize atıyoruz.Bu kod sonrasında çıktımız aşağıdaki gibi olacaktır.

Okunan De?er:Merhaba Dünya
Okunan De?er:Merhaba ve Dünya kelimelerini put komutu ile birle?tirdik.

Şimdi csv dosyamızın okumasını ve çıktısını kontrol edelim.

declare
  vOutFileCsv utl_file.file_type;
  vDeger      varchar2(4000);
begin
  vOutFileCsv := utl_file.fopen('ORADIR', 'csvfile.csv', 'r');

  if utl_file.is_open(vOutFileCsv) then
    loop
      begin
        utl_file.get_line(vOutFileCsv, vDeger);

        if vDeger is null then
          exit;
        end if;

        dbms_output.put_line('Okunan Değer:' || vDeger);
      exception
        when no_data_found then
          exit;
      end;
    end loop;

  end if;
  utl_file.fclose(vOutFileCsv);

exception
  when others then
    dbms_output.put_line('Hata:' || sqlerrm);
end;

Okuma işleminden sonra ise çıktımız aşağıdaki gibi olacaktır.

Okunan De?er:Syra;Açyklama;Tarih
Okunan De?er:1;1. Satyr;27/10/2013 13:21
Okunan De?er:2;2. Satyr;27/10/2013 13:21
Okunan De?er:3;3. Satyr;27/10/2013 13:21
Okunan De?er:4;4. Satyr;27/10/2013 13:21
Okunan De?er:5;5. Satyr;27/10/2013 13:21
Okunan De?er:6;6. Satyr;27/10/2013 13:21
Okunan De?er:7;7. Satyr;27/10/2013 13:21
Okunan De?er:8;8. Satyr;27/10/2013 13:21
Okunan De?er:9;9. Satyr;27/10/2013 13:21
Okunan De?er:10;10. Satyr;27/10/2013 13:21

Yukarıdaki işlemler ile benzer şekilde istenilen okuma ve yazma işlemleri yapılabilinir. Mevcut dosyaya bilgi eklemek için ise sadece "w" mod ile açılan dosya örneğinde olduğu gibi "w" yerine "a" ya da "A" yazmak yeterli olacaktır. Artık directory ve utl_fie kullanarak nasıl dosya oluşturacağımız bildiğimize göre hazırladığımız programlarda istediğimiz gibi fiziksel disk üzerine veri yazabilir, kodlarımızı log kayıtlarını atabilir ve ihtiyacımız olan ne varsa yapabiliriz.

Kolay gelsin.