Append hintini kullanarak uzun süren "insert ... select" işlemlerini sanki direct-path insert gibi çalıştırırız. Bunun için insert ten sonra /*+APPEND*/ yazılır. Örneğin

INSERT /*+ APPEND */ INTO target_table SELECT * FROM source_table;

Yukarıdaki gibi kullanıma gideriz. Oracle Append hintini gördüğü zaman insert ederken yarım yada tam dolmamış data bloklarını aramaktan vazgeçip, en son data blocklara eklemelere yaparak gelen datayı buraya kayıt etmektedir. Buraya kadar yazdıklarımı hemen hemen herkesin bildiği bir konuydu, fakat APPEND hintini bulk insertlerde kullanılmıyordu. Bulk insertin yapısı gereği "insert ... values .." yapısı kullanılıyordu. Böyle olunca da burada "insert /*+append*/ into... values .." hint verilse de oracle append hintini kullanmıyordu. Böyle kullanım senaryosunda sorunu çözmek için Oracle 11G Release 2'de gelen yenilikler arasında APPEND_VALUES hinti de bulunmaktadır. APPEND_VALUES hinti bulk insertlerde de APPEND hintinin avantajlarından yararlanmızı sağlamaktadır. Şimdi bunu bir örnek üzerinde denerek aradaki farkları görelim.

insertleri yapacağımız tabloyu hazırlayalım.

CREATE TABLE etl_user.append_test_table (
  id_col           NUMBER(10),
  code_col         VARCHAR2(10),
  desc_col  VARCHAR2(50)
);

ALTER TABLE etl_user.append_test_table ADD (CONSTRAINT append_test_table_pk PRIMARY KEY (id_col));

ALTER TABLE etl_user.append_test_table ADD (CONSTRAINT append_test_table_uk UNIQUE (code_col)); 

Insert into.. select.. ile  başlayalım.

DECLARE
   l_start_time   NUMBER;
BEGIN
   EXECUTE IMMEDIATE 'TRUNCATE TABLE APPEND_TEST_TABLE';

   l_start_time := DBMS_UTILITY.get_time;

   INSERT INTO append_test_table
      SELECT     LEVEL, TO_CHAR (LEVEL), 'Description: ' || TO_CHAR (LEVEL)
            FROM DUAL
      CONNECT BY LEVEL <= 500000;

   DBMS_OUTPUT.put_line (   'insert into ... select : '
                         || (DBMS_UTILITY.get_time - l_start_time)
                        );
   ROLLBACK;
END;

--insert into ... select : 797
--PL/SQL procedure successfully completed.

Şimdi append hintini kullanalım.

DECLARE
   l_start_time   NUMBER;
BEGIN
   EXECUTE IMMEDIATE 'TRUNCATE TABLE APPEND_TEST_TABLE';

   l_start_time := DBMS_UTILITY.get_time;

   INSERT /*+APPEND*/ INTO append_test_table
      SELECT     LEVEL, TO_CHAR (LEVEL), 'Description: ' || TO_CHAR (LEVEL)
            FROM DUAL
      CONNECT BY LEVEL <= 500000;

   DBMS_OUTPUT.put_line (   'insert into ... select : '
                         || (DBMS_UTILITY.get_time - l_start_time)
                        );
   ROLLBACK;
END;

--insert into ... select : 625
--PL/SQL procedure successfully completed.

Şimdi de bulk insert ve bulk insert'te append_values kullanarak aynı işlemi yapalım.

DECLARE
   TYPE t_test_tab IS TABLE OF append_test_table%ROWTYPE;

   l_tab     t_test_tab := t_test_tab ();
   l_start_time   NUMBER;
   l_size    NUMBER            := 1000000;
   
   PROCEDURE  sp_prepare_test_table
   AS
   BEGIN
      EXECUTE IMMEDIATE 'TRUNCATE TABLE APPEND_TEST_TABLE';

      INSERT      /*+ APPEND */INTO append_test_table
         SELECT     LEVEL, TO_CHAR (LEVEL),
                    'Description: ' || TO_CHAR (LEVEL)
               FROM DUAL
         CONNECT BY LEVEL <= l_size;

      COMMIT;

      DELETE FROM append_test_table
            WHERE MOD (ID_COL, 2) = 0;


      COMMIT;
   END sp_prepare_test_table;  
    
BEGIN

   FOR i IN 1 .. (l_size / 2)
   LOOP
      l_tab.EXTEND;
      l_tab (l_tab.LAST).id_col := i * 2;
      l_tab (l_tab.LAST).code_col := TO_CHAR (i * 2);
      l_tab (l_tab.LAST).desc_col := 'Description: ' || TO_CHAR (i * 2);
   END LOOP;

   
   sp_prepare_test_table;
-- ----------------------------------------------------------------
-- Test 1: Bulk insert.
   
   l_start_time := DBMS_UTILITY.get_time;
   
   FORALL i IN l_tab.FIRST .. l_tab.LAST
      INSERT INTO append_test_table
           VALUES l_tab (i);
   
   DBMS_OUTPUT.put_line (   'Bulk Inserts : '
                         || (DBMS_UTILITY.get_time - l_start_time)
                        );
-- ----------------------------------------------------------------
   ROLLBACK;
   
   sp_prepare_test_table;
-- ----------------------------------------------------------------
-- Test 2: Bulk insert APPEND_VALUES hint.
   
   l_start_time := DBMS_UTILITY.get_time;
   
   FORALL i IN l_tab.FIRST .. l_tab.LAST
      INSERT      /*+ APPEND_VALUES */INTO append_test_table
           VALUES l_tab (i);
   
   DBMS_OUTPUT.put_line (   'Bulk Inserts /*+ APPEND_VALUES */ : '
                         || (DBMS_UTILITY.get_time - l_start_time)
                        );
-- ----------------------------------------------------------------
   ROLLBACK;
   
END;

--Bulk Inserts : 656
--Bulk Inserts /*+ APPEND_VALUES */ : 490
--PL/SQL procedure successfully completed.